jeremy
eed5879a25
- Add --connect-timeout 5 --max-time 30 to all curl calls (starship, lazydocker, fastfetch, eza) so an unreachable/slow host aborts instead of hanging the new shell during a bootstrap version bump - Add -f/--fail to curl calls so a 502/HTML error page is not saved as a tarball or piped into sh - Guard fastfetch extract: only cp/chmod when $ffdir is non-empty, preventing cp of '/usr/bin/fastfetch' and glob against '/' when curl/tar fails - Only run fastfetch/eza copy steps when both curl and tar succeed; clean up temp tarballs in both success and failure paths - git clone now uses GIT_TERMINAL_PROMPT=0 and http.lowSpeedLimit/ lowSpeedTime so a stalled clone aborts after ~10s of no progress and an unexpected credential prompt cannot block startup - Drop invalid -y flag from 'dnf list available' availability check (it is a global dnf option, not a list subcommand arg) which could cause the check to fail and skip the dnf path
98 lines
3.7 KiB
Bash
98 lines
3.7 KiB
Bash
export ZSH_CONFIG=$HOME/.config/zsh
|
|
export OHMYZSH=$ZSH_CONFIG/oh-my-zsh
|
|
export OHMYZSH_CUSTOM=$OHMYZSH/custom
|
|
|
|
touch ~/.hushlogin
|
|
mkdir -p "$HOME/.local/bin"
|
|
mkdir -p "$ZSH_CONFIG"
|
|
path+=("$HOME/.local/bin")
|
|
|
|
for p in git starship fzf eza rsync lazydocker fastfetch tmux; do
|
|
command -v $p >/dev/null && continue
|
|
if command -v brew >/dev/null; then
|
|
echo "Installing $p using brew" && brew install $p && continue
|
|
fi
|
|
if command -v apt >/dev/null && apt-cache show $p >/dev/null 2>&1; then
|
|
echo "Installing $p using Apt" && sudo apt install $p -y && continue
|
|
fi
|
|
if command -v dnf >/dev/null && dnf list available $p >/dev/null 2>&1; then
|
|
echo "Installing $p using dnf" && sudo dnf install $p -y && continue
|
|
fi
|
|
if command -v pacman >/dev/null && pacman -Si $p >/dev/null 2>&1; then
|
|
echo "Installing $p using pacman" && sudo pacman -Sy --noconfirm $p && continue
|
|
fi
|
|
if command -v cargo >/dev/null; then
|
|
echo "Installing $p using cargo" && cargo install $p --locked && continue
|
|
fi
|
|
done
|
|
|
|
if ! command -v starship >/dev/null; then
|
|
echo "Installing starship binary..." && \
|
|
curl -fsSL --connect-timeout 5 --max-time 30 https://starship.rs/install.sh | sh -s -- -b ~/.local/bin -y >/dev/null 2>&1
|
|
fi
|
|
|
|
if ! command -v lazydocker >/dev/null; then
|
|
echo "Installing lazydocker binary..." && \
|
|
curl -fsSL --connect-timeout 5 --max-time 30 https://raw.githubusercontent.com/jesseduffield/lazydocker/master/scripts/install_update_linux.sh | \
|
|
DIR=$HOME/.local/bin bash >/dev/null 2>&1
|
|
fi
|
|
|
|
arch=$(uname -m)
|
|
case "$arch" in
|
|
x86_64) target_fast="linux-amd64" && target_eza="x86_64-unknown-linux-gnu" ;;
|
|
aarch64|arm64) target_fast="linux-aarch64" && target_eza="aarch64-unknown-linux-gnu" ;;
|
|
armv7l) target_fast="linux-armv7l" && target_eza="armv7-unknown-linux-gnueabihf" ;;
|
|
esac
|
|
|
|
if [[ -n $target_fast && -n $target_eza ]]; then
|
|
if ! command -v fastfetch >/dev/null; then
|
|
if curl -fsSL --connect-timeout 5 --max-time 30 -o /tmp/fastfetch.tar.gz \
|
|
"https://github.com/fastfetch-cli/fastfetch/releases/latest/download/fastfetch-${target_fast}.tar.gz" \
|
|
&& tar -xzf /tmp/fastfetch.tar.gz -C /tmp 2>/dev/null; then
|
|
ffdir=$(find /tmp -maxdepth 1 -type d -name 'fastfetch*' | head -1)
|
|
if [[ -n "$ffdir" ]]; then
|
|
cp "$ffdir/usr/bin/fastfetch" "$HOME/.local/bin/"
|
|
chmod +x "$HOME/.local/bin/fastfetch"
|
|
mkdir -p "$HOME/.local/share/fastfetch"
|
|
cp -r "$ffdir/usr/share/fastfetch/"* "$HOME/.local/share/fastfetch/"
|
|
fi
|
|
rm -rf "$ffdir" /tmp/fastfetch.tar.gz
|
|
else
|
|
rm -f /tmp/fastfetch.tar.gz
|
|
fi
|
|
fi
|
|
|
|
if ! command -v eza >/dev/null; then
|
|
if curl -fsSL --connect-timeout 5 --max-time 30 -o /tmp/eza.tar.gz \
|
|
"https://github.com/eza-community/eza/releases/latest/download/eza_${target_eza}.tar.gz" \
|
|
&& tar -xzf /tmp/eza.tar.gz -C "$HOME/.local/bin/" 2>/dev/null; then
|
|
chmod +x "$HOME/.local/bin/eza"
|
|
else
|
|
echo "Warning: failed to download eza" >&2
|
|
fi
|
|
rm -f /tmp/eza.tar.gz
|
|
fi
|
|
fi
|
|
|
|
mkdir -p "$HOME/.config/zsh"
|
|
|
|
[ ! -d $OHMYZSH ] && \
|
|
GIT_TERMINAL_PROMPT=0 git -c http.lowSpeedLimit=1000 -c http.lowSpeedTime=10 \
|
|
clone --depth=1 https://github.com/ohmyzsh/ohmyzsh.git $OHMYZSH
|
|
|
|
for plug in \
|
|
"zsh-autosuggestions|https://github.com/zsh-users/zsh-autosuggestions" \
|
|
"fast-syntax-highlighting|https://github.com/zdharma-continuum/fast-syntax-highlighting" \
|
|
"fzf-tab|https://github.com/Aloxaf/fzf-tab"
|
|
do
|
|
name="${plug%%|*}"
|
|
url="${plug##*|}"
|
|
dir="$OHMYZSH_CUSTOM/plugins/$name"
|
|
[[ ! -d "$dir" ]] && \
|
|
GIT_TERMINAL_PROMPT=0 git -c http.lowSpeedLimit=1000 -c http.lowSpeedTime=10 \
|
|
clone "$url" "$dir" 2>/dev/null
|
|
done
|
|
|
|
# Cleanup
|
|
[[ -d $HOME/.config/oh-my-zsh ]] && rm -rf "$HOME/.config/oh-my-zsh"
|